這篇文章主要講解了“怎么用bat批處理實(shí)現(xiàn)批量修改文件名”，文中的講解內(nèi)容簡單清晰，易于學(xué)習(xí)與理解，下面請大家跟著小編的思路慢慢深入，一起來研究和學(xué)習(xí)“怎么用bat批處理實(shí)現(xiàn)批量修改文件名”吧！

站在用戶的角度思考問題，與客戶深入溝通，找到海豐網(wǎng)站設(shè)計(jì)與海豐網(wǎng)站推廣的解決方案，憑借多年的經(jīng)驗(yàn)，讓設(shè)計(jì)與互聯(lián)網(wǎng)技術(shù)結(jié)合，創(chuàng)造個(gè)性化、用戶體驗(yàn)好的作品，建站類型包括：成都網(wǎng)站設(shè)計(jì)、網(wǎng)站制作、企業(yè)官網(wǎng)、英文網(wǎng)站、手機(jī)端網(wǎng)站、網(wǎng)站推廣、國際域名空間、網(wǎng)頁空間、企業(yè)郵箱。業(yè)務(wù)覆蓋海豐地區(qū)。

我們已經(jīng)會使用循環(huán)命令對大量文件改名進(jìn)行批量處理。但總結(jié)一下，該批處理并不是很健壯。

判斷一個(gè)程序的好壞，往往不是站在程序員的角度，而從用戶的角度出發(fā)。

比如：在用戶使用它的時(shí)候，如果輸入了不正確的路徑格式怎么辦？如果輸入了含有非法符號的前綴怎么辦？輸入的擴(kuò)展名也有問題怎么辦？改完名后看不到是否執(zhí)行成功的反饋信息，等等。帶著這些想法，我們將原程序再次修改一下。

:::::::批量修改文件名.bat:::::::
@echo off
title 批量修改文件名
setlocal EnableDelayedExpansion
:: 啟用延遲變量擴(kuò)充

:GetPath
set zpath=%CD%
:: 對變量進(jìn)行初始化，防止用戶不輸入而直接跳過。其中%CD%表示當(dāng)前路徑
set /p zpath=請輸入目標(biāo)文件所在的路徑：
if %zpath:~0,1%%zpath:~-1%=="" set zpath=%zpath:~1,-1%
:: 檢查變量 zpath 的第一個(gè)和最后一個(gè)字符是否為 "" ，是的話就去掉
if not exist "%zpath%" goto :GetPath
:: 如果 zpath 值的路徑不存在，就得跳轉(zhuǎn)回去，要求重新輸入

:GetPrefix
set prefix=未命名
set /p prefix=請輸入文件名前綴(不能包含以下字符\/:*?"<>|)：
for /f "delims=\/:*?<>| tokens=2" %%i in ("z%prefix%z") do goto :GetPrefix
:: 這里對變量 perfix 進(jìn)行檢查，發(fā)現(xiàn)有非法符號便跳轉(zhuǎn)到 :GetPrefix
:: 事實(shí)上，這里并沒有對雙引號 " 進(jìn)行檢測，因?yàn)殡p引號無法在此被轉(zhuǎn)義為可用的分隔符
:: 即使是在這個(gè)程序里，不正確地使用雙引號也會引起程序異常而退出。
:: 因此，想把它做的非常人性化并不是一件容易的事情

:GetExt
set ext=.*
set /p ext=請輸入文件的擴(kuò)展名(不輸入則表示所有類型)：
if not "%ext:~0,1%"=="." set ext=.%ext%
:: 檢查變量 ext 的第一個(gè)是否為句點(diǎn) . ，不是的話就加上
:: 建議這里對變量 ext 也檢查一下，發(fā)現(xiàn)有除*外的非法符號便跳轉(zhuǎn)到 :GetExt

set answer=N
echo.
echo 您試圖將 %zpath%\ 里的所有 %ext% 類型的文件以 %prefix% 為前綴名進(jìn)行批量改名，是否繼續(xù)？
set /p answer=繼續(xù)請輸入 Y ，輸入其它鍵放棄...
if "%answer%"=="Y" goto :ReadyToRename
if "%answer%"=="y" goto :ReadyToRename

echo 放棄文件改名，按任意鍵退出... & goto :PauseThenQuit

:ReadyToRename

set /a num=0
echo.

if "%ext%"==".*" (
  for %%i in ("%zpath%\*%ext%") do (
    set /a num+=1
    ren "%%i" "%prefix%!num!%%~xi" || echo 文件 %%i 改名失敗 && set /a num-=1
  )
) else (
  for %%i in ("%zpath%\*%ext%") do (
    set /a num+=1
    ren "%%i" "%prefix%!num!%ext%" || echo 文件 %%i 改名失敗 && set /a num-=1
  )
)

if %num%==0 echo %zpath%\ 里未發(fā)現(xiàn)任何文件。按任意鍵退出... & goto :PauseThenQuit

echo 文件改名完成，按任意鍵退出...

:PauseThenQuit
pause>nul
::::::::::::::::::::::::::::::::

感謝各位的閱讀，以上就是“怎么用bat批處理實(shí)現(xiàn)批量修改文件名”的內(nèi)容了，經(jīng)過本文的學(xué)習(xí)后，相信大家對怎么用bat批處理實(shí)現(xiàn)批量修改文件名這一問題有了更深刻的體會，具體使用情況還需要大家實(shí)踐驗(yàn)證。這里是創(chuàng)新互聯(lián)網(wǎng)站建設(shè)公司，，小編將為大家推送更多相關(guān)知識點(diǎn)的文章，歡迎關(guān)注！

本文題目：怎么用bat批處理實(shí)現(xiàn)批量修改文件名-創(chuàng)新互聯(lián)
本文URL：http://www.aaarwkj.com/article42/gjiec.html

成都網(wǎng)站建設(shè)公司_創(chuàng)新互聯(lián)，為您提供網(wǎng)站設(shè)計(jì)、網(wǎng)站改版、全網(wǎng)營銷推廣、網(wǎng)站設(shè)計(jì)公司、品牌網(wǎng)站建設(shè)、移動(dòng)網(wǎng)站建設(shè)

廣告

聲明：本網(wǎng)站發(fā)布的內(nèi)容（圖片、視頻和文字）以用戶投稿、用戶轉(zhuǎn)載內(nèi)容為主，如果涉及侵權(quán)請盡快告知，我們將會在第一時(shí)間刪除。文章觀點(diǎn)不代表本網(wǎng)站立場，如需處理請聯(lián)系客服。電話：028-86922220；郵箱：631063699@qq.com。內(nèi)容未經(jīng)允許不得轉(zhuǎn)載，或轉(zhuǎn)載時(shí)需注明來源： 創(chuàng)新互聯(lián)